/todo

#!/usr/bin/perl

use strict;

use warnings;

use Getopt::Long;

use File::Basename;

# get app name

my $app_name = basename( $0 );

# option defaults

my $todo_dir = "~/.todo";

my $display_all = 0;

my $display_section = "TODO";

my $display_headers = 0;

my $mode_edit = 0;

my $mode_help = 0;

my $mode_version = 0;

# parse command line opts

Getopt::Long::Configure( 'gnu_getopt' );

if( !GetOptions(

    'a|all' => \$display_all,

    'e|edit' => \$mode_edit,

    'h|headers' => \$display_headers,

    'section=s' => \$display_section,

    'help' => \$mode_help,

    'version' => \$mode_version,

) ) {

    print "Try `$app_name --help' for more information.\n";

    exit( 1 );

}

# help mode

if( $mode_help ) {

    print "todo - display your todo file\n\n".

	"Usage: $app_name [OPTIONS]\n\n".

	"Options:\n".

	"  -a, --all              display all sections\n".

	"  -e, --edit             edit your todo file\n".

	"  -h, --headers          show setion headers\n".

	"  -s, --section=SECTION  display this named section\n".

	"      --help     display this help and exit\n".

	"      --version  output version information and exit\n";

    exit( 0 );

}

# version mode

if( $mode_version ) {

    print "todo 1.0\n" .

	"Copyright (C) 2011 Tim Marston.\n";

    exit( 0 );

}

#_______________________________________________________________________________

# check we have bazaar installed

my $output = `which bzr`;

chomp $output;

$output eq "" and die "Bazaar is not installed";

# glob todo directory

$todo_dir = glob( $todo_dir );

( -f $todo_dir ) and die "$todo_dir exists and is a file";

# edit mode

if( $mode_edit )

{

    # create the todo directory, as necessary

	if( ! -d $todo_dir ) {

		mkdir $todo_dir or die "couldn't create todo directory";

		`bzr init --no-aliases -q "$todo_dir"`;

		$? == 0 or die "couldn't init bzr repo";

	}

	# create a default todo file, as necessary

	if( ! -f "$todo_dir/todo" ) {

		open FILE, ">$todo_dir/todo" or die "couldn't create default todo file";

		my $content = <<"EOT";

<!-- This file uses Markdown syntax. For more info about Markdown

     syntax, see http://daringfireball.net/projects/markdown/syntax.

     There should be a main H1 header called "TODO" for the main todo

     list section (one has been added for you below). You can also add

     as many more sections as you like for other lists. And feel free

     to delete this comment! -->

TODO

====

* make a list of things to do

EOT

        print FILE $content or die "couldn't write default todo file";

		close FILE;

		`bzr add --no-aliases -q "$todo_dir/todo"`;

		$? == 0 or die "couldn't add todo file to bzr repo";

	}

    # determine editor from environment, default to "emacs -nw"

    my $editor = $ENV{ 'EDITOR' };

    defined $editor or $editor = 'emacs -nw';

    my @exec_array = split( / +/, $editor );

    push( @exec_array, "$todo_dir/todo" );

	# detect emacs and try to use markdown-mode

	$exec_array[ 0 ] eq "emacs" and

		push( @exec_array, '--funcall=markdown-mode' );

    # edit todo file

    system( @exec_array );

	$? == 0 or die "unable to exec editor";

	# check for changes and commit it

	$output = `bzr status --no-aliases "$todo_dir/todo"`;

	$? == 0 or die "couldn't check bzr rerpo status";

	chomp $output;

	if( $output ne "" ) {

		`bzr commit --no-aliases -q -m - "$todo_dir/todo"`;

		$? == 0 or die "couldn't commit to bzr repo";

	}

	# after editing, exit

	exit

}

# scan through file

my $next_section = '';

my $section = '';

my $old_section = '';

open FILE, "<$todo_dir/todo" or die "can't open todo file";

while( <FILE> ) {

    my $display = 0;

    # detect the line after section headings, and thus sections

    if( /^[-=]{2,}/ && $next_section ne '' ) {

		$section = $next_section;

		$next_section = '';

    }

    # detect section headings

    elsif( /^[A-Z]+$/ ) {

		$next_section = $_;

		chomp( $next_section );

    }

    # we have neither a section heading nor the line after

    else {

		$next_section = '';

		# display line

		if( ( $section eq $display_section ) ||

			( $section && $display_all ) )

		{

			# detect section change

			if( $section ne $old_section ) {

				$old_section = $section;

				# display section heading

				if( $display_headers ||

					$display_all )

				{

					print "$section\n".

						( "=" x length( $section ) )."\n";

				}

			}

			# replace tabs with 4 spaces

			s/\t/    /g;

			# display the line

			print;

		}

    }

}